7.5.3 Defining new classes of frame

7.5.3.2 Specifying panes for a new class of frame

In the same way that you can define slots, you can define panes for a frame class using pane options. Panes may be used to define all the visual aspects of a frame class, including such things as:

The layouts and gadgets displayed in the frame
The menu bar, menus, and menu commands available in the frame
Additional components, such as tool bars or status bars

Typically, the definition for any pane has the following syntax:

pane pane-name (pane-owner) pane-definition;

This breaks down into the following elements:

The reserved word pane.
The name you wish to give the pane, which acts as a slot accessor for the frame, to let you retrieve the pane.
A space in which you can bind the owner of the pane (usually the frame itself) to a local variable for use inside the pane definition
The definition of the pane

Once you have defined all the visual components of a frame using an arrangement of panes of your choice, each major component needs to be included in the frame using an appropriate clause. For example, to include a tool bar, having created a pane called app-tool-bar that contains the definition of the tool bar itself, you need to include the following code at the end of the definition of the frame:

tool-bar (frame) frame.app-tool-bar;

The major components that need to be activated in any frame definition are the top level layout, menu bar, tool bar, and status bar.

The following example shows how to define and activate panes within a frame.

Three panes are defined:

button: A push button that contains a simple callback.
status: A status bar.
main-layout: A column layout that consists of the button pane, together with a drawing pane.

define frame <example-frame> (<simple-frame>)

... other code here

// pane definitions
  pane button (frame) 
    make(<push-button>,
         label: "Press",
         activate-callback: 
           method (button) 
             notify-user (format-to-string ("Pressed button"),
                            owner: frame)
           end);
  pane status (frame)
    make(<status-bar>);
  pane main-layout (frame)
    vertically (spacing: 10)
      horizontally (borders: 2, x-alignment: #"center")
        frame.button;
      end;
      make(<drawing-pane>,
           foreground: $red); 
    end;

... other code here

// activate components of frame
  layout (frame) frame.main-layout;
  status-bar (frame) frame.status;
// frame title
  keyword title: = "Example Frame";
end frame <example-frame>;

The following method creates an instance of an <example-frame>.

The simplest way to create an example frame is by calling this method thus: make-example-frame();.

define method make-example-frame => (frame :: <example-frame>)
  let frame
    = make(<example-frame>);
  start-frame(frame);
end method make-example-frame;

For a more complete example of how to define your own class of frame for use in an application, see the chapters that cover the development of the Task List Manager in this manual (Chapters 2 to 6).